MS03-016: Cumulative Patch for Microsoft BizTalk Server

if exists (select * from sysobjects where id = object_id(N'[dbo].[dta_ui_cookies]') 
    and OBJECTPROPERTY(id, N'IsUserTable') = 1) 
drop table [dbo].[dta_ui_cookies] 

if exists (select * from sysobjects where id = object_id(N'[dbo].[dta_ui_get_cookie]') 
    and OBJECTPROPERTY(id, N'IsProcedure') = 1) 
drop procedure [dbo].[dta_ui_get_cookie] 

if exists (select * from sysobjects where id = object_id(N'[dbo].[dta_ui_verify_cookie]') 
    and OBJECTPROPERTY(id, N'IsProcedure') = 1) 
drop procedure [dbo].[dta_ui_verify_cookie] 
GO 

CREATE TABLE [dbo].[dta_ui_cookies] 
    ( nvcCookie nvarchar(40) NOT NULL, 
      dtTimeStamp datetime NOT NULL DEFAULT GetDate(), )
GO 

CREATE PROCEDURE [dbo].[dta_ui_get_cookie] 
AS 
SET NOCOUNT ON 
declare @nvcCookie nvarchar(40) 
set @nvcCookie = CAST(NEWID() as nvarchar(40)) 
select @nvcCookie as N'Cookie' 
insert into dta_ui_cookies (nvcCookie) values (@nvcCookie) 
SET NOCOUNT OFF 
return 
GO 

CREATE PROCEDURE [dbo].[dta_ui_verify_cookie] @nvcCookie nvarchar(40) 
AS 
SET NOCOUNT ON 
declare @nSuccess int 
set @nSuccess = 0 
if exists ( select * from dta_ui_cookies where nvcCookie = @nvcCookie AND DATEDIFF(ss, dtTimeStamp, GETDATE()) <= 60 ) 
    begin 
        set @nSuccess = 1 
    end 
select @nSuccess as 'Success' 
delete from dta_ui_cookies where nvcCookie = @nvcCookie OR DATEDIFF(ss, dtTimeStamp, GETDATE()) > 60 
SET NOCOUNT OFF 
return 
GO 

GRANT EXEC ON [dbo].[dta_ui_get_cookie] TO dta_ui_role 
GRANT EXEC ON [dbo].[dta_ui_verify_cookie] TO dta_ui_role 
GO