Internet Explorer does not load the Hover button ActiveX control after you install security update 912812 in FrontPage 2003

Option Explicit

Sub ReplaceHoverButtons()

    Dim applet As IHTMLElement
    Dim param As IHTMLElement
    Dim objHead As IHTMLElement
    
    Dim theWeb As WebEx
    Dim webFiles As webFiles
    Dim webFile As webFile
    
    Dim buttonText As String
    Dim buttonURL As String
    Dim buttontarget As String
    Dim styleBlock As String
    

    Set theWeb = ActiveWeb
    Set webFiles = theWeb.RootFolder.AllFiles
    
    ' build the style block with colors that match default hover buttons from sample document
    styleBlock ="<style type=""text/css"">" & vbCrLf & _
   "#hoverButton {width: 150px;background-color: #FFFFFF;position: relative;" & _
   "clear: both;display: inline;font-family:Arial;Helvetica;sans-serif}" & vbCrLf & _
   "#hoverButton a {list-style-type: none;width: 100%;margin: 0;" & _
   "text-decoration: none;color: #CC6600;" & _
   "display:block;padding: 5px;border-bottom: 1px solid #f2f2f2;}" & vbCrLf & _
   "#hoverButton a:hover {text-decoration: none;color: #000000;" & _
   "border-bottom: 1px solid #f2f2f2;background-color: #FF9933;}" & vbCrLf & _
   "</style>"

    For Each webFile In webFiles
      
        If webFile.Extension ="htm" Or _
        webFile.Extension ="aspx" Or _
        webFile.Extension ="asp" Or _
        webFile.Extension ="html" Then
        
        ' open the file
        webFile.Open
        
        ' Add style block to each of the pages
        Set objHead = ActiveDocument.all.tags("head").Item(0)
        Call objHead.insertAdjacentHTML("BeforeEnd", styleBlock)

        ' loop through the applets to get target, url and text to display
        For Each applet In ActiveDocument.all.tags("applet")
            
            ' only get the values for hover buttons
            If applet.getAttribute("code") ="fphover.class" Then
                
                For Each param In applet.Children
                    
                    ' get the value of the target
                    If param.getAttribute("name") ="target" Then
                        buttontarget = param.getAttribute("value")
                    End If
                    
                    ' get the value of the URL
                    If param.getAttribute("name") ="url" Then
                        buttonURL = param.getAttribute("value")
                    End If
                    
                    ' get the value of the display text
                    If param.getAttribute("name") ="text" Then
                        buttonText = param.getAttribute("value")
                    End If
    
                Next

            End If
            
            ' replace the applet with new html based on the settings from above
            applet.outerHTML ="<span id=""hoverButton""><a href=""" & buttonURL &""" target=""" & buttontarget &""">" & buttonText &"</a></span>"
        Next
        ' save the page - don't worry about the embedded files dialog
        ActiveDocument.Save (False)
        ActivePageWindow.Close (False)

        End If
    Next
    ' uncomment the next line to close the web
    'theWeb.Close
    
End Sub