FIX: You cannot download a message attachment from the OWA server if the OWA server is published by using ISA Server 2006 or Forefront TMG 2010

Consider the following scenario:

• You publish a Microsoft Office Outlook Web Access (OWA) server for Microsoft Exchange Server 2007 by using Microsoft Internet Security and Acceleration (ISA) Server 2006 or Microsoft Forefront Threat Management Gateway (TMG) 2010.
• You set the publishing rule to use the NT LAN Manager (NTLM) delegation.
• You log on to OWA, you open a message in a separate window, and then you open an attachment of the message.

In this scenario, the attachment download fails.

Note The supported fix for Forefront TMG 2010 is included in Forefront TMG 2010 Service Pack 1 (SP1).

This issue occurs because ISA Server 2006 or Forefront TMG 2010 sometimes adds a "Pragma: no-cache" header to a response from Exchange Server 2007. When this happens, Windows Internet Explorer cannot cache the attachment. Therefore, Internet Explorer cannot download the attachment.

Service pack information

This problem is fixed in Forefront TMG 2010 Service Pack 1.

For more information about how to obtain Forefront TMG 2010 Service Pack 1, click the following article number to view the article in the Microsoft Knowledge Base:

Hotfix rollup information

Hotfix installation information

To resolve this problem, follow these steps:

1. Install the hotfix rollup package that is described in the following Microsoft Knowledge Base (KB) article:
   977530� Description of the ISA Server 2006 hotfix package: December 8, 2009
2. Start Notepad, and then copy the following script into a Notepad file.

   Const SE_VPS_GUID = "{143F5698-103B-12D4-FF34-1F34767DEabc}"
   Const SE_VPS_NAME = "EnableHotfix976495"
   Const SE_VPS_VALUE = true
   
   Sub SetValue()
   
       ' Create the root object.
       Dim root  ' The FPCLib.FPC root object
       Set root = CreateObject("FPC.Root")
   
       'Declare the other objects that are needed.
       Dim array       ' An FPCArray object
       Dim VendorSets  ' An FPCVendorParametersSets collection
       Dim VendorSet   ' An FPCVendorParametersSet object
   
       ' Get references to the array object
       ' and to the network rules collection.
       Set array = root.GetContainingArray
       Set VendorSets = array.VendorParametersSets
   
       On Error Resume Next
       Set VendorSet = VendorSets.Item( SE_VPS_GUID )
   
       If Err.Number <> 0 Then
           Err.Clear
   
           ' Add the item
           Set VendorSet = VendorSets.Add( SE_VPS_GUID )
           CheckError
           WScript.Echo "New VendorSet added... " & VendorSet.Name
   
       Else
           WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value(SE_VPS_NAME)
       End If
   
       if VendorSet.Value(SE_VPS_NAME) <> SE_VPS_VALUE Then
   
           Err.Clear
           VendorSet.Value(SE_VPS_NAME) = SE_VPS_VALUE
   
           If Err.Number <> 0 Then
               CheckError
           Else
               VendorSets.Save false, true
               CheckError
   
               If Err.Number = 0 Then
                   WScript.Echo "Done with " & SE_VPS_NAME & ", saved!"
               End If
           End If
       Else
           WScript.Echo "Done with " & SE_VPS_NAME & ", no change!"
       End If
   
   End Sub
   
   Sub CheckError()
   
       If Err.Number <> 0 Then
           WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
           Err.Clear
       End If
   
   End Sub
   
   SetValue

3. Save the file as a Microsoft Visual Basic script file by using the .vbs file name extension. For example, assume that you save the file by using the following name:
   EnableKB976495.vbs
4. Double-click the .vbs file to run it.

Microsoft has confirmed that this is a problem in the Microsoft products that are listed in the "Applies to" section. This problem was first corrected in Forefront TMG 2010 Service Pack 1.

For more information about software update terminology, click the following article number to view the article in the Microsoft Knowledge Base: