An update is available for ISA Server 2006 Service Pack 1 that enables source-based Web proxy chaining

In Microsoft Internet Security and Acceleration (ISA) Server 2006, Web proxy chaining enables a downstream proxy to route Web requests to an upstream proxy, instead of sending them directly to the Web server. A Web proxy chaining rule is applied to the destination of a Web request, regardless of its source.

This article describes an update for ISA Server 2006 Service Pack 1 (SP1) that enables source-based Web proxy chaining. When this update is enabled, you can exclude certain source addresses from Web proxy chaining, regardless of the destination of the Web request. Web requests that come from these source addresses are not chained to an upstream proxy. They are routed directly to the destination.

Update information

A supported feature that modifies the default behavior of the product is available from Microsoft. However, this feature is intended to modify only the behavior that this article describes. Apply this feature only to systems that specifically require it.

If the feature is available for download, there is a "Hotfix download available" section at the top of this Knowledge Base article. If this section does not appear, contact Microsoft Customer Service and Support to obtain the feature.

Note If additional issues occur or if any troubleshooting is required, you might have to create a separate service request. The usual support costs will apply to additional support questions and issues that do not qualify for this specific feature. For a complete list of Microsoft Customer Service and Support telephone numbers or to create a separate service request, visit the following Microsoft Web site: Note The "Hotfix download available" form displays the languages for which the feature is available. If you do not see your language, it is because the feature is not available for that language.

To enable this update, follow these steps:

1. Download and then install the update package.
2. Start Notepad, copy the following script into a file, and then change the script according to your settings.

   '
   ' Copyright (c) Microsoft Corporation. All rights reserved.
   ' THIS CODE IS MADE AVAILABLE AS IS, WITHOUT WARRANTY OF ANY KIND. THE ENTIRE
   ' RISK OF THE USE OR THE RESULTS FROM THE USE OF THIS CODE REMAINS WITH THE
   ' USER. USE AND REDISTRIBUTION OF THIS CODE, WITH OR WITHOUT MODIFICATION, IS
   ' HEREBY PERMITTED.
   ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
   
   Const SE_VPS_GUID = "{143F5698-103B-12D4-FF34-1F34767DEabc}"
   Const SE_VPS_NAME = "RangesForChainExclusion"
   Const SE_VPS_VALUE = "<source subnet>/<subnet mask>;<source subnet>/<subnet mask>;�
   
   Sub SetValue()
   
       ' Create the root object.
       Dim root  ' The FPCLib.FPC root object
       Set root = CreateObject("FPC.Root")
   
       'Declare the other objects needed.
       Dim array       ' An FPCArray object
       Dim VendorSets  ' An FPCVendorParametersSets collection
       Dim VendorSet   ' An FPCVendorParametersSet object
   
       ' Get references to the array object
       ' and the network rules collection.
       Set array = root.GetContainingArray
       Set VendorSets = array.VendorParametersSets
   
       On Error Resume Next
       Set VendorSet = VendorSets.Item( SE_VPS_GUID )
   
       If Err.Number <> 0 Then
           Err.Clear
   
           ' Add the item.
           Set VendorSet = VendorSets.Add( SE_VPS_GUID )
           CheckError
           WScript.Echo "New VendorSet added... " & VendorSet.Name
   
       Else
           WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value(SE_VPS_NAME)
       End If
   
       Err.Clear
       VendorSet.Value(SE_VPS_NAME) = SE_VPS_VALUE
   
       If Err.Number <> 0 Then
           CheckError
       Else
           VendorSets.Save false, true
           CheckError
   
           If Err.Number = 0 Then
               WScript.Echo "Done with " & SE_VPS_NAME & ", saved!"
           End If
       End If
   
   End Sub
   
   Sub CheckError()
   
       If Err.Number <> 0 Then
           WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
           Err.Clear
       End If
   
   End Sub
   
   SetValue
   

   Note You must use the appropriate source subnets and subnet masks to replace the placeholders in the following line.

   Const SE_VPS_VALUE = "<source subnet>/<subnet mask>;<source subnet>/<subnet mask>;�
   

   For example, modify the line as follows.

   Const SE_VPS_VALUE = "10.10.0.0/255.255.0.0;172.16.10.0/255.255.255.0;"

   In this example, Web requests that come from subnets 10.10.0.0/16 and 172.16.10.0/24 are routed directly to the destination, regardless of any Web proxy chaining rules that redirect to an upstream proxy. The semicolon must appear even if there is only one source subnet.
3. Save the file as a Microsoft Visual Basic script file by using the .vbs file name extension. For example, save the file as configRangesForChainExclusion.vbs in the C:\configRangesForChainExclusion folder.
4. At a command prompt, move to the location of the .vbs file, and then run the .vbs file. For example, run the following commands:
   cd C:\ configRangesForChainExclusion
   cscript configRangesForChainExclusion.vbs

Prerequisites

To apply this update, you must have ISA Server 2006 SP1 installed on the computer.

For more information, click the following article number to view the article in the Microsoft Knowledge Base:

Restart requirement

You do not have to restart the computer after you apply this update. However, the update installation restarts the ISA Server 2006-related services.

Update replacement information

This update does not replace any other updates.

File information

The English version of this update has the file attributes (or later file attributes) that are listed in the following table. The dates and times for these files are listed in Coordinated Universal Time (UTC). When you view the file information, it is converted to local time. To find the difference between UTC and local time, use the Time Zone tab in the Date and Time item in Control Panel.

For more information about Web proxy chaining, visit the following Microsoft Web site:For more information about software update terminology, click the following article number to view the article in the Microsoft Knowledge Base: