The global address book does not contain the addresses of customers and the addresses of vendors even though you import all customer data to the CustTable table and import all vendor data to the VendTable table in Microsoft Dynamics AX 2009

// ---code begin-----
// The job is used to create the missing address entries for the VendTable table.
static void generateDirPartyEntriesVendTable(Args _args)
{
    VendTable   vendTable;
    VendTable   vendTableNoLock;
    ;
    while select vendTableNoLock
    {
        setPrefix(strFmt("Vendor %1",vendTableNoLock.AccountNum));
        try
        {
            ttsBegin;
            vendTable = VendTable::find(vendTableNoLock.AccountNum,true);
            if (vendTable)
            {
                if (vendTable.PartyId && !DirPartyTable::exist(vendTable.PartyId))
                {
                    vendTable.PartyId = "";
                }
                if (!vendTable.PartyId)
                {
                    // Create a Party entry for a vendor.
                    vendTable.PartyId = DirParty::createPartyFromCommon(vendTable).PartyId;
                }
                else
                {
                    DirParty::updatePartyFromCommonInsert(vendTable.PartyId,vendTable);
                }
                vendTable.update();
            }
            ttsCommit;
        }
        catch
        {
            error(strFmt("There has been an error while updating the vendor '%1'.",vendTableNoLock.AccountNum));
        }
    }
}
// ---code end-----

// ---code begin---
// The job is used to create the missing address entries for the CustTable table.

static void generateDirPartyEntriesCustTable(Args _args)
{
    CustTable   custTable;
    CustTable   custTableNoLock;
    ;
    while select custTableNoLock
    {
        setPrefix(strFmt("Customer %1",custTableNoLock.AccountNum));
        try
        {
            ttsBegin;
            custTable = CustTable::find(custTableNoLock.AccountNum,true);
            if (custTable)
            {
                if (custTable.PartyId && !DirPartyTable::exist(custTable.PartyId))
                {
                    custTable.PartyId = "";
                }
                if (!custTable.PartyId)
                {
                    // Create a Party entry for a customer.
                    custTable.PartyId = DirParty::createPartyFromCommon(custTable).PartyId;
                }
                else
                {
                    DirParty::updatePartyFromCommonInsert(custTable.PartyId,custTable);
                }
                custTable.update();
            }
            ttsCommit;
        }
        catch
        {
            error(strFmt("There has been an error while updating the customer '%1'.",custTableNoLock.AccountNum));
        }
    }
}
// ---code end-----