FIX: After you configure the rules in ISA Server 2006 to apply to all users, ISA Server may sometimes try to authenticate users

'------------------------------------------------------------------------EnablePortPermAuthen begin
Sub RemoveDisablePortPermissionAuthentication()

    ' Create the root obect.
    Dim root  ' The FPCLib.FPC root object
    Set root = CreateObject("FPC.Root")

    'Declare the other objects needed.
    Dim array       ' An FPCArray object
    Dim VendorSets  ' An FPCVendorParametersSets collection
    Dim VendorSet   ' An FPCVendorParametersSet object

    ' Get references to the array object
    ' and the network rules collection.
    Set array = root.GetContainingArray
    Set VendorSets = array.VendorParametersSets

    On Error Resume Next
    Set VendorSet = VendorSets.Item( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )

    If Err.Number <> 0 Then
        Err.Clear

        ' Add the item
        Set VendorSet = VendorSets.Add( "{143F5698-103B-12D4-FF34-1F34767DEabc}" )
        CheckError
        WScript.Echo "New VendorSet added... " & VendorSet.Name

    Else
        WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value("DisablePortPermissionAuthentication")
    End If

    if VendorSet.Value("DisablePortPermissionAuthentication") <> false Then

        Err.Clear
        VendorSet.Value("DisablePortPermissionAuthentication") = false

        If Err.Number <> 0 Then
            CheckError
        Else
            VendorSets.Save false, true
            CheckError

            If Err.Number = 0 Then
                WScript.Echo "Done with EnablePortPermissionAuthentication, saved!"
            End If
        End If
    Else
        WScript.Echo "Done with EnablePortPermissionAuthentication, no change!"
    End If

End Sub

Sub CheckError()

    If Err.Number <> 0 Then
        WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
        Err.Clear
    End If

End Sub

RemoveDisablePortPermissionAuthentication
'------------------------------------------------------------------------EnablePortPermAuthen end