Error message when you open a .gz file that you downloaded through an ISA Server 2004 or ISA Server 2006 Web proxy server: "Invalid archive directory"

You download a file that has a .gz file name extension through a Microsoft Internet Security and Acceleration (ISA) 2004 or ISA Server 2006 Web proxy server. When you open the .gz file, you receive an error message that resembles the following:Note This problem occurs if the response from the Web server contains a content-type header that has the value APPLICATION/G-ZIP.

This problem occurs because ISA Server 2004 and ISA Server 2006 decompress the .gz file before it is downloaded to the computer. This issue occurs if HTTP compression is enabled in ISA Server 2004.

Note By default, ISA Server 2004 and ISA Server 2006 do not send the Accept-Encoding HTTP header to the Web server. They send the Accept-Encoding HTTP header only when you enable HTTP compression.

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure. However, they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

To resolve this problem, follow these steps:

1. For ISA Server 2004: Install the hotfix that is described in the following Microsoft Knowledge Base article:
   951958 Description of the ISA Server 2004 hotfix package: April 21, 2008
   For ISA Server 2006: Download and install the latest service pack:
   954258 How to obtain the latest Internet Security and Acceleration (ISA) Server 2006 Service Pack
2. For both versions of ISA Server, run the Visual Basic script to enable the update. To do this, follow these steps:
   1. Click Start, point to All Programs, point to Accessories, and then click Notepad.
   2. Paste the following code into the Notepad document.

      Const SE_VPS_GUID = "{143F5698-103B-12D4-FF34-1F34767DEabc}"
      Const SE_VPS_NAME = "EnableHotfix950150"
      Const SE_VPS_VALUE = true
      
      Sub SetValue()
      
          ' Create the root obect.
          Dim root  ' The FPCLib.FPC root object
          Set root = CreateObject("FPC.Root")
      
          'Declare the other objects needed.
          Dim array       ' An FPCArray object
          Dim VendorSets  ' An FPCVendorParametersSets collection
          Dim VendorSet   ' An FPCVendorParametersSet object
      
          ' Get references to the array object
          ' and the network rules collection.
          Set array = root.GetContainingArray
          Set VendorSets = array.VendorParametersSets
      
          On Error Resume Next
          Set VendorSet = VendorSets.Item( SE_VPS_GUID )
      
          If Err.Number <> 0 Then
              Err.Clear
      
              ' Add the item
              Set VendorSet = VendorSets.Add( SE_VPS_GUID )
              CheckError
              WScript.Echo "New VendorSet added... " & VendorSet.Name
      
          Else
              WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value(SE_VPS_NAME)
          End If
      
          if VendorSet.Value(SE_VPS_NAME) <> SE_VPS_VALUE Then
      
              Err.Clear
              VendorSet.Value(SE_VPS_NAME) = SE_VPS_VALUE
      
              If Err.Number <> 0 Then
                  CheckError
              Else
                  VendorSets.Save false, true
                  CheckError
      
                  If Err.Number = 0 Then
                      WScript.Echo "Done with " & SE_VPS_NAME & ", saved!"
                  End If
              End If
          Else
              WScript.Echo "Done with " & SE_VPS_NAME & ", no change!"
          End If
      
      End Sub
      
      Sub CheckError()
      
          If Err.Number <> 0 Then
              WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
              Err.Clear
          End If
      
      End Sub
      
      SetValue
      

   3. Save the Notepad file as Enable_9501050.vbs.
   4. Double-click the Enable_9501050.vbs file to run the script.

Hotfix installation information

Prerequisites

For ISA Server 2004, the computer must be running ISA Server 2004 Service Pack 3 (SP3). For more information about ISA Server 2004 SP3, click the following article number to view the article in the Microsoft Knowledge Base: For ISA Server 2006, the latest service pack must be installed. For more information about how to obtain the latest service pack, click the following article number to view the article in the Microsoft Knowledge Base:

Restart requirement

ISA services are automatically restarted after you install the ISA Server 2004 hotfix or the ISA Server 2006 service pack.

Microsoft has confirmed that this is a bug in the Microsoft products that are listed in the "Applies to" section.

For more information about how to install ISA Server hotfixes and updates, click the following article number to view the article in the Microsoft Knowledge Base: