ISA Server 2004 blocks compressed file attachments if the "Block responses containing Windows executable content" option is enabled in the HTTP filter settings

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' Copyright (c) Microsoft Corporation. All rights reserved.
' THIS CODE IS MADE AVAILABLE AS IS, WITHOUT WARRANTY OF ANY KIND. THE ENTIRE
' RISK OF THE USE OR THE RESULTS FROM THE USE OF THIS CODE REMAINS WITH THE
' USER. USE AND REDISTRIBUTION OF THIS CODE, WITH OR WITHOUT MODIFICATION, IS
' HEREBY PERMITTED.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
	
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' This script sets whether ISA will treat the 'Content-Encoding: none' response header 
' to mean that the content is not encoded for a specified rule
'
' usage - to enable this functionality run the script as follows:-
' cscript AllowNoneEncoding.vbs rulename
'
' where rulename is the name of the OWA Web pubishing rule
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Const SE_VPS_GUID = "{143F5698-103B-12D4-FF34-1F34767DEabc}"
Const SE_VPS_NAME = "AllowNoneEncoding"
Const SE_VPS_VALUE = true


'Define the constants needed
const Error_FileNotFound = &H80070002
Const fpcPolicyWebPublishing = 2

Main(WScript.Arguments)

Sub Main(args)

    If(args.Count = 1) Then
        SetAllowNoneEncoding args(0)
    Else
        Usage()
    End If
End Sub

Sub SetAllowNoneEncoding(ruleName)

    ' Create the root object.
    Dim root  ' The FPCLib.FPC root object
    Set root = CreateObject("FPC.Root")

    ' Declare the other objects needed.
    Dim isaArray        ' An FPCArray object
    Dim rule            ' An FPCPolicyRule object

    ' Obtain a reference to the array object.
    Set isaArray = root.GetContainingArray()

    ' Obtain a reference to the policy rule specified.
    On Error Resume Next
    Set rule = isaArray.ArrayPolicy.PolicyRules.Item(ruleName)
    If Err.Number = Error_FileNotFound Then
        WScript.Echo "The policy rule specified could not be found."
    Else
        Err.Clear
        On Error GoTo 0
        If rule.Type = fpcPolicyWebPublishing Then

            Dim VendorSets  ' An FPCVendorParametersSets collection
            Dim VendorSet   ' An FPCVendorParametersSet object

            Set VendorSets = rule.VendorParametersSets

            On Error Resume Next
            Set VendorSet = VendorSets.Item( SE_VPS_GUID )

            If Err.Number <> 0 Then
                Err.Clear

                ' Add the item
                Set VendorSet = VendorSets.Add( SE_VPS_GUID )
                CheckError
                WScript.Echo "New VendorSet added... " & VendorSet.Name

            Else
                WScript.Echo "Existing VendorSet found... value- " &  VendorSet.Value(SE_VPS_NAME)
            End If

            if VendorSet.Value(SE_VPS_NAME) <> SE_VPS_VALUE Then

                Err.Clear
                VendorSet.Value(SE_VPS_NAME) = SE_VPS_VALUE

                If Err.Number <> 0 Then
                        CheckError
                End If
            End If

            rule.Save
            WScript.Echo "Done!"

        Else
            WScript.Echo "The policy rule specified is not a Web publishing rule."
        End If
    End If

End Sub

Sub Usage()
    WScript.Echo "Usage:" & VbCrLf _
        & "  " & WScript.ScriptName & " RuleName" & VbCrLf _
        & "" & VbCrLf _
        & "    RuleName - Name of the Web publishing rule"
    WScript.Quit
End Sub


Sub CheckError()

    If Err.Number <> 0 Then
        WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
        Err.Clear
    End If

End Sub