Moveuser.exe is incompatible with Windows Vista and is replaced by the new Win32_UserProfile WMI functionality

Information about how to use the User Profile WMI provider

• The source user profile cannot be private.
  
• Any folder redirection to a local volume or to a server must be disabled.
• Access to the following settings is not preserved:
  • Encrypted files
  • Certificates
  • The user account picture
• Disable encryption for any files before you map any profile to another new user account profile.
• User saved passwords will not be mapped from the local profile to the domain profile. Therefore, the user will be prompted to reenter these passwords the first time that they access the associated program. For example, the user will be prompted to reenter the password for Windows Live Messenger the first time that they start the program after the profile is moved.
• The User Profile WMI provider is implemented like other WMI interfaces by using WMI tools, scripts, or applications that use the WMI COM interface. For more information about how to use WMI, see the"About WMI" topic at the following MSDN Web site:
  http://msdn2.microsoft.com/en-us/library/aa384642.aspx
• To learn specifically about the management functions that the User Profile WMI provider supports, use a repository browsing tool to explore the class in the \root\CIMV2 namespace.

Visual Basic script examples

• The following Microsoft Visual Basic script example retrieves a user profile object through the user name and the domain and then deletes the user profile object.

  strComputer ="."
   
  Set objAccount = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" _
                              & strComputer &"\root\cimv2:Win32_UserAccount." _
                              &"Domain='contoso',Name='fabrikam'")    
   
  Set objUserProfile = GetObject("winmgmts:{impersonationlevel=impersonate}!\\" _
                                 & strComputer &"\root\cimv2:Win32_UserProfile." _
                                 &"SID='" & objAccount.SID &"'")
   
  objUserProfile.Delete_
  

• RoamingPreferenceis the only property that can be set by a user who has administrative credentials. The following Visual Basic script example retrieves and displays information about all the profiles on the local computer.
  • To run the Visual Basic script against a remote computer, set the value of the strComputer variable to the name or the IP address of the remote computer. The placeholder RemoteComputerName is used to set the variable in the following example:
    
    strComputer = “RemoteComputerName”.
  • When you run this script by using Wscript.exe, one series of message boxes is displayed for each profile. You receive one message box for each profile. You have to click OKto close each message.
  • To avoid these message boxes, run the script by using Cscript.exe instead of Wscript.exe. When you use Cscript.exe, the information is displayed at the command prompt instead of as message boxes. To run the following script by using Cscript.exe, type cscript.exe script_nameat the command prompt, and then press ENTER.

strComputer ="."
Set objWMIService = GetObject("winmgmts:\\" & strComputer &"\root\cimv2")
Set colProfiles = objWMIService.ExecQuery("Select * from Win32_UserProfile")
For Each objProfile in colProfiles
    Set objSID = objWMIService.Get("Win32_SID.SID='" & objProfile.SID &"'")
    Wscript.Echo"======================================================"& VBNewLine _
        &"Sid:" & objProfile.Sid & VBNewLine _
        &"User Name:" & objSID.AccountName & VBNewLine _
        &"User Domain:" & objSID.ReferencedDomainName & VBNewLine _
        &"LocalPath:" & objProfile.LocalPath & VBNewLine _
        &"Loaded:" & objProfile.Loaded & VBNewLine _
        &"RefCount:" & objProfile.RefCount & VBNewLine _
        &"RoamingConfigured:" & objProfile.RoamingConfigured & VBNewLine _
        &"RoamingPath:" & objProfile.RoamingPath & VBNewLine  _
        &"RoamingPreference:" & objProfile.RoamingPreference & VBNewLine _
        &"Status:" & objProfile.Status & VBNewLine _
        &"LastUseTime:" & objProfile.LastUseTime & VBNewLine  _
        &"LastDownloadTime:" & objProfile.LastDownloadTime & VBNewLine  _
        &"LastUploadTime:" & objProfile.LastUploadTime & VBNewLine  
Next