Error message when you try to open a linked SharePoint table in Access 2007: "The Microsoft Office Access database engine could not find the object"

Sample subroutine to delete the relationships

1. Insert the following code into a module in Microsoft Visual Basic for Applications (VBA):

   Public Sub RemoveInvalidRelationships(strTableName As String)
       On Error Resume Next
       Dim cnt As Integer
       Dim i As Integer
       Dim bForeignTable As Boolean
       Dim bTable As Boolean
       Dim td As TableDef
       
       cnt = CurrentDb.Relations.Count - 1
       ' Go through the relationships collection backwards, to ensure that if we delete one, we will have a valid index
       For i = cnt To 0 Step -1
           bTable = False
           bForeignTable = False
           If (StrComp(CurrentDb.Relations(i).Table, strTableName, vbTextCompare) = 0) Then bTable = True
           If (StrComp(CurrentDb.Relations(i).ForeignTable, strTableName, vbTextCompare) = 0) Then bForeignTable = True
           
           If bTable Xor bForeignTable Then
               ' Determine if either the table or foreign table is the table that we are interested in
               ' We will then look at the other table to determine if it exists
               ' If it doesn't exist, delete the relationship
               If bTable Then
                   Set td = CurrentDb.TableDefs(CurrentDb.Relations(i).ForeignTable)
               Else
                   Set td = CurrentDb.TableDefs(CurrentDb.Relations(i).Table)
               End If
               
               If Err.Number = 3265 Then
                   CurrentDb.Relations.Delete CurrentDb.Relations(i).Name
               End If
               Err.Clear
           End If
           
       Next i
   End Sub
   

2. In the source code where the RefreshLink method is called, insert the following code immediately before the RefreshLink source code line:

   RemoveInvalidRelationships "WSSLink"

   Note "WSSLink" is the name of the linked table that is being refreshed by the RefreshLink method.