A large file download fails when an ISA Server 2004 SOCKS client computer or an ISA Server 2006 SOCKS client computer uses passive mode FTP

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' Copyright (c) Microsoft Corporation. All rights reserved.
' THIS CODE IS MADE AVAILABLE AS IS, WITHOUT WARRANTY OF ANY KIND. THE ENTIRE
' RISK OF THE USE OR THE RESULTS FROM THE USE OF THIS CODE REMAINS WITH THE
' USER. USE AND REDISTRIBUTION OF THIS CODE, WITH OR WITHOUT MODIFICATION, IS
' HEREBY PERMITTED.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' This script sets the idle connection time-out value for the SOCKS filter.
' The value is in seconds.
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Sub SetSocksIdleTimeout()

    ' Create the root object.
    Dim root  ' The FPCLib.FPC root object
    Set root = CreateObject("FPC.Root")

    'Declare the other objects needed.
    Dim array       ' An FPCArray object
    Dim Extensions  ' An FPCExtensions object
    Dim ApplicationFilters ' An FPCApplicationFilters object
    Dim ApplicationFilter  ' An FPCApplicationFilter object
    Dim VendorSets  ' An FPCVendorParametersSets collection
    Dim VendorSet   ' An FPCVendorParametersSet object

    ' Get references to the array object
    Set array = root.GetContainingArray

    On Error Resume Next

    Set Extensions = array.Extensions
    CheckError

    Set ApplicationFilters = Extensions.ApplicationFilters
    CheckError

    Set ApplicationFilter = ApplicationFilters.Item("{25765C04-C80B-494C-914E-286297DB8C8E}")

    Set VendorSets = ApplicationFilter.VendorParametersSets
    Set VendorSet = VendorSets.Item( "{25765C04-C80B-494C-914E-286297DB8C8E}" )

    VendorSet.Value("SessionIdleTimeoutSeconds") = 120 ' value in seconds to be set to desired value

    ApplicationFilter.Save false, true

    WScript.Echo "Done..."

End Sub

Sub CheckError()

    If Err.Number <> 0 Then
        WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
        Err.Clear
    End If

End Sub

SetSocksIdleTimeout