How to use the HttpWebRequest class and the HttpWebResponse class to delete an object by using Visual Basic .NET

Imports System.Net
Imports System.IO

Module Module1
    Sub Main()
        ' TODO: Replace with the object URL that is to be deleted.
        Dim sUri As String = "http://<ExchServer>/Exchange/<UserAlias>/Inbox/NewFolder"

        Dim myUri As System.Uri = New System.Uri(sUri)
        Dim HttpWRequest As HttpWebRequest = WebRequest.Create(myUri)

        ' Set Credentials
        ' TODO: Replace with an appropriate user credential.
        Dim myCred As NetworkCredential = New NetworkCredential("Domain\UserName", "Password")
        Dim MyCredentialCache As CredentialCache = New CredentialCache()
        MyCredentialCache.Add(myUri, "Basic", myCred)
        HttpWRequest.Credentials = MyCredentialCache

        'Uncomment the following statement and comment the previous 4 statements if you
        'use Integrated Windows authentication
        'HttpWRequest.Credentials = CredentialCache.DefaultCredentials

        'Note In Basic type authentication, username and password are sent as base64-encoded text and is 
        'easily decoded. Microsoft recommends that you use Basic instead of SSL to help protect the username and password.        

        ' Set Headers
        HttpWRequest.KeepAlive = False
        HttpWRequest.Headers.Set("Pragma", "no-cache")

        'Set the request timeout to 5 minutes.
        HttpWRequest.Timeout = 300000
        ' set the request method
        HttpWRequest.Method = "DELETE"

        ' Send the request and get the response.
        Dim HttpWResponse As HttpWebResponse = HttpWRequest.GetResponse()

        ' Get the status and the headers.
        Dim iStatCode As Integer = HttpWResponse.StatusCode
        Dim sStatus As String = iStatCode.ToString()
        Console.WriteLine("Status: {0} {1}", sStatus, HttpWResponse.StatusDescription.ToString())

        Console.WriteLine("Request Headers:")
        Console.WriteLine(HttpWRequest.Headers.ToString())
        Console.WriteLine("Response Headers:")
        Console.WriteLine(HttpWResponse.Headers.ToString())

        ' Get the response stream.
        Dim strm As Stream = HttpWResponse.GetResponseStream()

        ' Read the response stream.
        Dim sr As StreamReader = New StreamReader(strm)
        Dim sText As String = sr.ReadToEnd()
        Console.WriteLine("Response: {0}", sText)

        ' Close the stream.
        strm.Close()

        ' Clean up
        HttpWRequest = Nothing
        HttpWResponse = Nothing
        MyCredentialCache = Nothing
        myCred = Nothing
        strm = Nothing
        sr = Nothing
    End Sub
End Module