ACC2000: How to Create a Table with Jet Data Types via ADOX

Sub ADOX_CreateJetTable()

'This example demonstrates creating a Jet table with
'Autoincrement, Decimal, and Memo columns.

Dim tbl As New ADOX.Table
Dim cat As New ADOX.Catalog

'Return Reference to current database.
Set cat.ActiveConnection = CurrentProject.Connection

'Assign the new table name.

With tbl
  .Name = "MyNewTable"

    ' Append new columns to the table.
    With .Columns
      .Append "MyID", adInteger
      .Append "MyMemo", adLongVarWChar
      .Append "MyVarChar", adWChar, 50
      .Append "MyDecimal", adNumeric
    
            'After appending columns, set
            'provider specific properties.
            With !MyID
                Set .ParentCatalog = cat
                    .Properties("Autoincrement") = True
                    .Properties("seed") = CLng(20)
                    .Properties("increment") = CLng(20)
            End With
    
    
            With !MyDecimal
                Set .ParentCatalog = cat
                    .Precision = 2
                    .NumericScale = 1
            End With
    
            With !MyVarChar
                Set .ParentCatalog = cat
                    .Properties("Jet OLEDB:Compressed " _
                                & "UniCode Strings") = True
            End With
    
    End With
End With

' Append new table to the provider catalog and clean up.
cat.Tables.Append tbl
Set cat = Nothing

End Sub