You experience slow performance when you post an invoice that has many lines in Microsoft Dynamics NAV 2009

Installation information

Code changes

1. Delete the SalesLine parameter in the TestGetShipmentPPmtAmtToDeduct function in the Sales-post codeunit (80).
2. Replace the existing variables in the TestGetShipmentPPmtAmtToDeduct function in the Sales-post codeunit (80) with the following:

   SalesLine2@1170000004 : Record 37;
   TempSalesLine3@1170000003 : TEMPORARY Record 37;
   TempTotalSalesLine@1170000002 : TEMPORARY Record 37;
   TempSalesShptLine@1170000001 : TEMPORARY Record 111;
   MaxAmtToDeduct@1170000000 : Decimal;

3. Replace the existing code in the TestGetShipmentPPmtAmtToDeduct function in the Sales-post codeunit (80) with the following:

   SalesLine2.SETRANGE("Document Type",SalesHeader."Document Type");
   SalesLine2.SETRANGE("Document No.",SalesHeader."No.");
   SalesLine2.SETFILTER(Quantity,'>0');
   SalesLine2.SETFILTER("Qty. to Invoice",'>0');
   SalesLine2.SETFILTER("Shipment No.",'<>%1','');
   SalesLine2.SETFILTER("Prepmt Amt to Deduct",'<>0');
   IF SalesLine2.ISEMPTY THEN
     EXIT;
   SalesLine2.SETRANGE("Prepmt Amt to Deduct");
   IF SalesLine2.FINDSET THEN
     REPEAT
       IF SalesShptLine.GET(SalesLine2."Shipment No.",SalesLine2."Shipment Line No.") THEN BEGIN
         TempSalesLine3 := SalesLine2;
         TempSalesLine3.INSERT;
         TempSalesShptLine := SalesShptLine;
         IF TempSalesShptLine.INSERT THEN;
         IF NOT TempTotalSalesLine.GET(SalesLine2."Document Type"::Order,SalesShptLine."Order No.",SalesShptLine."Order Line No.")
         THEN BEGIN
           TempTotalSalesLine.INIT;
           TempTotalSalesLine."Document Type" := SalesLine2."Document Type"::Order;
           TempTotalSalesLine."Document No." := SalesShptLine."Order No.";
           TempTotalSalesLine."Line No." := SalesShptLine."Order Line No.";
           TempTotalSalesLine.INSERT;
         END;
         TempTotalSalesLine."Qty. to Invoice" := TempTotalSalesLine."Qty. to Invoice" + SalesLine2."Qty. to Invoice";
         TempTotalSalesLine."Prepmt Amt to Deduct" := TempTotalSalesLine."Prepmt Amt to Deduct" + SalesLine2."Prepmt Amt to Deduct";
         TempTotalSalesLine.MODIFY;
       END;
     UNTIL SalesLine2.NEXT = 0;
   IF TempSalesLine3.FINDSET THEN
     REPEAT
       IF TempSalesShptLine.GET(TempSalesLine3."Shipment No.",TempSalesLine3."Shipment Line No.") THEN BEGIN
         IF SalesLine2.GET(TempSalesLine3."Document Type"::Order,TempSalesShptLine."Order No.",TempSalesShptLine."Order Line No.") THEN
           IF TempTotalSalesLine.GET(TempSalesLine3."Document Type"::Order,TempSalesShptLine."Order No.",
              TempSalesShptLine."Order Line No.")
           THEN BEGIN
             MaxAmtToDeduct := SalesLine2."Prepmt. Amt. Inv." - SalesLine2."Prepmt Amt Deducted";
             IF TempTotalSalesLine."Prepmt Amt to Deduct" > MaxAmtToDeduct THEN
               ERROR(STRSUBSTNO(Text050,SalesLine2.FIELDCAPTION("Prepmt Amt to Deduct"),MaxAmtToDeduct));
             IF (TempTotalSalesLine."Qty. to Invoice" = SalesLine2.Quantity - SalesLine2."Quantity Invoiced") AND
                (TempTotalSalesLine."Prepmt Amt to Deduct" <> MaxAmtToDeduct)
             THEN
               ERROR(STRSUBSTNO(Text051,SalesLine2.FIELDCAPTION("Prepmt Amt to Deduct"),MaxAmtToDeduct));
           END;
       END;
     UNTIL TempSalesLine3.NEXT = 0;

4. Change the code in the CreatePrepaymentLines function in the Sales-post codeunit (80) as follows:
   Existing code

   ... 
       IF NOT PrePmtTestRun THEN BEGIN
         TestGetShipmentPPmtAmtToDeduct(SalesHeader,SalesLine);
         PrePmtTestRun := TRUE;
       END;
   ...

   Replacement code

   ...
       IF NOT PrePmtTestRun THEN BEGIN
         TestGetShipmentPPmtAmtToDeduct(SalesHeader);
         PrePmtTestRun := TRUE;
       END;
   ...

5. Delete the PurchaseLine parameter in the TestGetRcptPPmtAmtToDeduct function in the Purch.-post codeunit (90).
6. Replace the existing variables in the TestGetRcptPPmtAmtToDeduct function in the Purch.-post codeunit (90) with the following:

   PurchLine2@1170000004 : Record 39;
   TempPurchLine3@1170000003 : TEMPORARY Record 39;
   TempTotalPurchLine@1170000002 : TEMPORARY Record 39;
   TempPurchRcptLine@1170000001 : TEMPORARY Record 121;
   MaxAmtToDeduct@1170000000 : Decimal;

7. Replace the exisitng code in the TestGetRcptPPmtAmtToDeduct function in the Purch.-post codeunit (90) with the following:

   PurchLine2.SETRANGE("Document Type",PurchHeader."Document Type");
   PurchLine2.SETRANGE("Document No.",PurchHeader."No.");
   PurchLine2.SETFILTER(Quantity,'>0');
   PurchLine2.SETFILTER("Qty. to Invoice",'>0');
   PurchLine2.SETFILTER("Receipt No.",'<>%1','');
   PurchLine2.SETFILTER("Prepmt Amt to Deduct",'<>0');
   IF PurchLine2.ISEMPTY THEN
     EXIT;
   PurchLine2.SETRANGE("Prepmt Amt to Deduct");
   IF PurchLine2.FINDSET THEN
     REPEAT
       IF PurchRcptLine.GET(PurchLine2."Receipt No.",PurchLine2."Receipt Line No.") THEN BEGIN
         TempPurchLine3 := PurchLine2;
         TempPurchLine3.INSERT;
         TempPurchRcptLine := PurchRcptLine;
         IF TempPurchRcptLine.INSERT THEN;
         IF NOT TempTotalPurchLine.GET(PurchLine2."Document Type"::Order,PurchRcptLine."Order No.",PurchRcptLine."Order Line No.")
         THEN BEGIN
           TempTotalPurchLine.INIT;
           TempTotalPurchLine."Document Type" := PurchLine2."Document Type"::Order;
           TempTotalPurchLine."Document No." := PurchRcptLine."Order No.";
           TempTotalPurchLine."Line No." := PurchRcptLine."Order Line No.";
           TempTotalPurchLine.INSERT;
         END;
         TempTotalPurchLine."Qty. to Invoice" := TempTotalPurchLine."Qty. to Invoice" + PurchLine2."Qty. to Invoice";
         TempTotalPurchLine."Prepmt Amt to Deduct" := TempTotalPurchLine."Prepmt Amt to Deduct" + PurchLine2."Prepmt Amt to Deduct";
         TempTotalPurchLine.MODIFY;
       END;
     UNTIL PurchLine2.NEXT = 0;
   IF TempPurchLine3.FINDSET THEN
     REPEAT
       IF TempPurchRcptLine.GET(TempPurchLine3."Receipt No.",TempPurchLine3."Receipt Line No.") THEN BEGIN
         IF PurchLine2.GET(TempPurchLine3."Document Type"::Order,TempPurchRcptLine."Order No.",TempPurchRcptLine."Order Line No.") THEN
           IF TempTotalPurchLine.GET(
                TempPurchLine3."Document Type"::Order,TempPurchRcptLine."Order No.",TempPurchRcptLine."Order Line No.")
           THEN BEGIN
             MaxAmtToDeduct := PurchLine2."Prepmt. Amt. Inv." - PurchLine2."Prepmt Amt Deducted";
             IF TempTotalPurchLine."Prepmt Amt to Deduct" > MaxAmtToDeduct THEN
               ERROR(STRSUBSTNO(Text050,PurchLine2.FIELDCAPTION("Prepmt Amt to Deduct"),MaxAmtToDeduct));
             IF (TempTotalPurchLine."Qty. to Invoice" = PurchLine2.Quantity - PurchLine2."Quantity Invoiced") AND
                (TempTotalPurchLine."Prepmt Amt to Deduct" <> MaxAmtToDeduct)
             THEN
              ERROR(STRSUBSTNO(Text051,PurchLine2.FIELDCAPTION("Prepmt Amt to Deduct"),MaxAmtToDeduct));
           END;
       END;
     UNTIL TempPurchLine3.NEXT = 0;

8. Change the code in the CreatePrepaymentLines function in the Purch.-post codeunit (90) as follows:
   Existing code

   ...
           IF NOT PrePmtTestRun THEN BEGIN
       TestGetRcptPPmtAmtToDeduct(PurchHeader,PurchLine);
       PrePmtTestRun := TRUE;
     END;
   ...

   Replacement code

   ...
           IF NOT PrePmtTestRun THEN BEGIN
       TestGetRcptPPmtAmtToDeduct(PurchHeader);
       PrePmtTestRun := TRUE;
     END;
   ...

Prerequisites

• Microsoft Dynamics NAV 2009 R2
• Microsoft Dynamics NAV 2009 Service Pack 1 (SP1)

Removal information