FP2000: How to Add HTML to a File by Using Visual Basic for Applications

Sub AddHTML()

    ' Set up variables.
    Dim myDocument As FPHTMLDocument
    Dim myFile As WebFile
    Dim myPageWindow As PageWindow
    Dim myTag As IHTMLElement
    Dim myText As String

    ' Set myFile to equal the example.htm file.
    Set myFile = ActiveWeb.RootFolder.Files("example.htm")

    ' Set myPageWindow to equal myFile.
    ' We also use the Edit method to change the view to Normal view
    ' in case the file is opened. In order to insert the HTML, we must
    ' be in Normal view.
    Set myPageWindow = myFile.Edit(fpPageViewNormal)

    ' Set myDocument to equal the document contained in myPageWindow.
    Set myDocument = myPageWindow.Document

    ' Set myTag to equal the first BODY tag.
    ' The All collection referenced here contains a reference to all
    ' HTML tags on the page.
    Set myTag = myDocument.all.tags("body").Item(0)

    ' myText is the text we are going to insert.
    ' The <b> tag makes this text bold.
    myText = "<b>This was inserted with VBA!</b>"
        
    ' Call the insertAdjacentHTML method.
    ' Using this method, we add myText after the beginning BODY tag.
    Call myTag.insertAdjacentHTML("AfterBegin", myText)

    ' Now we save the page. We use the document's original URL.
    myPageWindow.SaveAs myPageWindow.Document.Url

    ' Then we close the page. We append False to this method so that 
    ' the method won't force the page to be saved again.
    myPageWindow.Close False

End Sub