How To Format Strings to Right-Justify When Printing

Using the @ character:

1. Format the number into a string with numeric conversion characters, for example, $##0.00.
   
2. Format the resulting string with a format string consisting of a number of @ characters equal in length to the desired format, for example, @@@@@@@.
   

   Print "|" & Format$(Format$(1.5, "$##0.00"), "@@@@@@@") & "|"
   Print "|" & Format$(Format$(12.5, "$##0.00"), "@@@@@@@") & "|"
   Print "|" & Format$(Format$(123.5, "$##0.00"), "@@@@@@@") & "|"

|  $1.50|
| $12.50|
|$123.50|
 

Using the RSet function:

   x = (Format$(123.5, "$##0.00"))
   Print "x" & x & "x"
   RSet x = (Format$(1.5, "$##0.00"))
   Print "x" & x & "x"

x$123.50x 
x  $1.50x
 

Workarounds using the Format$ function:

   required = 8 ' longest number expected
   a = 1.23
   b = 44.56
   num1$ = Format$(a, "#0.00") ' this converts the number to a string
   num2$ = Format$(b, "#0.00") ' with 2 decimal places and a leading zero
   'Debug.Print num2$
   If (required - Len(num1$)) > 0 Then
   num1$ = Space$(required - Len(num1$)) + num1$
   End If
   
   If (required - Len(num2$)) > 0 Then
   num2$ = Space$(required - Len(num2$)) + num2$
   End If
' test output
   Print num1$
   Print num2$

   1.23
  44.56
 

Private Function LPad(ValIn As Variant, nDec As Integer, _
                      WidthOut As Integer) As String
'
' Formatting function left pads with spaces, using specified
' number of decimal digits.
'
   If IsNumeric(ValIn) Then
      If nDec > 0 Then
         LPad = Right$(Space$(WidthOut) & _
                Format$(ValIn, "0." & String$(nDec, "0")), _
                WidthOut)
      Else
         LPad = Right$(Space$(WidthOut) & Format$(ValIn, "0"), WidthOut)
      End If
   Else
      LPad = Right$(Space$(WidthOut) & ValIn, WidthOut)
   End If
End Function

Step by Step Sample

1. Start a new Visual Basic Standard EXE project. Form1 is created by default.
   
2. Add four CommandButton controls to Form1. Position them to the far right of the form window.
   
3. Add the following code to the General Declarations section of Form1:

   Option Explicit
   
   Private Sub Command1_Click()
      Me.Print "|" & Format$(Format$(1.5, "$##0.00"), "@@@@@@@") & "|"
      Me.Print "|" & Format$(Format$(12.5, "$##0.00"), "@@@@@@@") & "|"
      Me.Print "|" & Format$(Format$(123.5, "$##0.00"), "@@@@@@@") & "|"
   End Sub
   
   Private Sub Command2_Click()
      Dim x As String
      x = (Format$(123.5, "$##0.00"))
      Me.Print "x" & x & "x"
      RSet x = (Format$(1.5, "$##0.00"))
      Me.Print "x" & x & "x"
   End Sub
   
   Private Sub Command3_Click()
      Dim required As Integer
      Dim a As Single
      Dim b As Single
      Dim num1$, num2$
   
      required = 8 ' longest number expected
      a = 1.23
      b = 44.56
      num1$ = Format$(a, "#0.00") ' this converts the number to a string
      num2$ = Format$(b, "#0.00") ' with two decimal places and a leading zero
      'Debug.Print num2$
      If (required - Len(num1$)) > 0 Then
         num1$ = Space$(required - Len(num1$)) & num1$
      End If
      
      If (required - Len(num2$)) > 0 Then
         num2$ = Space$(required - Len(num2$)) & num2$
      End If
   ' test output
      Me.Print num1$
      Me.Print num2$
   End Sub
   
   Private Sub Command4_Click()
      Dim xstring As String
      xstring = LPad(2.3, 2, 7)
      Me.Print "K" & xstring & "K"
   End Sub
   
   Private Sub Form_Load()
      Command1.Caption = "@"
      Command1.Font.Size = 18
      Command2.Caption = "Rset"
      Command3.Caption = "Format$"
      Command4.Caption = "VBPJ"
      Me.Font.Name = "Courier New"
   End Sub
   
   Private Function LPad(ValIn As Variant, nDec As Integer, _
                         WidthOut As Integer) As String
   '
   ' Formatting function left pads with spaces, using specified
   ' number of decimal digits.
   '
      If IsNumeric(ValIn) Then
         If nDec > 0 Then
            LPad = Right$(Space$(WidthOut) & _
                   Format$(ValIn, "0." & String$(nDec, "0")), _
                   WidthOut)
         Else
            LPad = Right$(Space$(WidthOut) & Format$(ValIn, "0"), WidthOut)
         End If
      Else
         LPad = Right$(Space$(WidthOut) & ValIn, WidthOut)
      End If
   End Function
   

4. Run the program, click the command buttons, and observe the results.