XL2000: Macro Code to Check Whether a File Is Already Open

When you use a file that is shared over a network, you may frequently find it useful to know if another user has the file open. The following Microsoft Visual Basic for Applications procedure is an example of a method for determining whether another user has a particular file open.

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs.
If you have limited programming experience, you may want to contact a Microsoft Certified Partner or Microsoft Advisory Services. For more information, visit these Microsoft Web sites:

Microsoft Certified Partners - https://partner.microsoft.com/global/30000104

Microsoft Advisory Services - http://support.microsoft.com/gp/advisoryservice

For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site:http://support.microsoft.com/default.aspx?scid=fh;EN-US;CNTACTMS

Sample Macro Code

If a given file is not already open, the following macro also opens it. If the file is not in the location you specified, you receive the following error message: To create a Visual Basic procedure to see if Book2.xls in drive C is already open, follow these steps:

1. Start Microsoft Excel, and then press ALT+F11 to open Visual Basic for Applications.
2. In Visual Basic, click Module on the Insert menu.
3. Type the following code in the module sheet:

   Sub TestFileOpened()
   
       ' Test to see if the file is open.
       If IsFileOpen("c:\Book2.xls") Then
           ' Display a message stating the file in use.
           MsgBox "File already in use!"
           '
           ' Add code here to handle case where file is open by another
           ' user.
           '
       Else
           ' Display a message stating the file is not in use.
           MsgBox "File not in use!"
           ' Open the file in Microsoft Excel.
           Workbooks.Open "c:\Book2.xls"
           '
           ' Add code here to handle case where file is NOT open by another
           ' user.
           '
       End If
   
   End Sub
   
   ' This function checks to see if a file is open or not. If the file is
   ' already open, it returns True. If the file is not open, it returns
   ' False. Otherwise, a run-time error occurs because there is
   ' some other problem accessing the file.
   
   Function IsFileOpen(filename As String)
       Dim filenum As Integer, errnum As Integer
   
       On Error Resume Next   ' Turn error checking off.
       filenum = FreeFile()   ' Get a free file number.
       ' Attempt to open the file and lock it.
       Open filename For Input Lock Read As #filenum
       Close filenum          ' Close the file.
       errnum = Err           ' Save the error number that occurred.
       On Error GoTo 0        ' Turn error checking back on.
   
       ' Check to see which error occurred.
       Select Case errnum
   
           ' No error occurred.
           ' File is NOT already open by another user.
           Case 0
            IsFileOpen = False
   
           ' Error number for "Permission Denied."
           ' File is already opened by another user.
           Case 70
               IsFileOpen = True
   
           ' Another error occurred.
           Case Else
               Error errnum
       End Select
   
   End Function
   					

For more information about how to use the sample code in this article, click the article number below to view the article in the Microsoft Knowledge Base: