ACC2000: How to Get Red, Green, Blue Components from RGB Value

Option Explicit
					

'-----------------------------------------------------------------
'PURPOSE: Returns red/green/blue color from RGB color value.
'
'ACCEPTS: RGB color value as Long, and component number as integer
'         that represents the component color to return (1=red,
'         2=green, 3=blue).
'
'RETURNS: The intensity of the color component (0 - 255) as an
'         integer or -1 indicating that an argument was invalid.
'-----------------------------------------------------------------

Function GetRGB(RGBval As Long, Num As Integer) As Integer
   ' Check if Num, RGBval are valid.
   If Num > 0 And Num < 4 And RGBval > -1 And RGBval < 16777216 Then
     GetRGB = RGBval \ 256 ^ (Num - 1) And 255
   Else
     ' Return True (-1) if Num or RGBval are invalid.
     GetRGB = True
   End If
End Function

'-----------------------------------------------------------------
'PURPOSE: Open the Orders form in Form view, call the GetRGB
'         function, and then switch the Orders form to Design view.
'
'ACCEPTS: RGB color value as Long, and component number as integer
'         that represents the component color to return (1=red,
'         2=green, 3=blue).
'
'RETURNS: Displays a message box with the RGB components
'         of the detail section of the Orders form.
'-----------------------------------------------------------------

Sub TestOrders()

   DoCmd.OpenForm "Orders", acNormal
   
   MsgBox "Red: " & GetRGB(Forms![Orders].Section(0).BackColor, 1) & _
          vbCrLf & _
          "Green: " &  GetRGB(Forms![Orders].Section(0).BackColor, 2) & _
          vbCrLf & _
          "Blue: " &   GetRGB(Forms![Orders].Section(0).BackColor, 3)

   DoCmd.OpenForm "Orders", acDesign
   
End Sub