ACC2000: How to Export All Modules in a Database to Text Files

Option Explicit
Public MyMsg as String, MyTitle as String ' Global variables.
					

Function OutPutModules(strMyloc As Variant)
'******************************************************************
' This function will export ALL modules in the current dbase as
' text files to the user supplied location or to the default
' location. This function will except an optional argument as the
' location to export to. The Optional argument should consist of a
' path to the location where you want to store the text files. If
' you don't supply the optional argument, the default location of
' c:\ will be used.
'******************************************************************
On Error GoTo OutPutModules_Error

Dim strMyMsg As String
Dim strMyTitle As String
Dim DB As DAO.Database
Dim strModuleName As String
Dim intI As Integer
Dim mdl As Module
Dim strMyExt As String
Dim strDisplayError As String
Dim strNewMsg As String
Dim strNewLoc As String

Set DB = CurrentDb()
' If user enters the backslash in the location, for example, 'A:\',
' parse out the '\' backslash, assign the drive letter and the colon
' ONLY to variable 'Myloc'.
If Right(strMyloc, 1) = "\" Then strMyloc = Left(strMyloc, _
   Len(strMyloc) - 1)
strMyExt = ".txt"  ' Set extension for file names.
' Loop through module names.
For intI = 0 To DB.Containers("Modules").Documents.Count - 1
   ' Set string variable(strModuleName) to module names.
   strModuleName = DB.Containers("Modules").Documents(intI).Name
   ' Print out ALL modules in designated format to designated
   ' drive/folder.
   strNewLoc = strMyloc & "\" & strModuleName & strMyExt
   DoCmd.OutputTo acOutputModule, strModuleName, acFormatTXT, _
      strNewLoc, 0
Next intI
' Display message with # of objects exported.
strNewMsg = intI & " Module Objects Exported" & Chr(13) & Chr(10)
strNewMsg = strNewMsg & "to " & strMyloc & "."
MsgBox strNewMsg, vbOK, "Export Objects"

Exit_OutPutModules:
   Exit Function

OutPutModules_Error:
   Set mdl = Modules(strModuleName)
   strMyTitle = "Error in Procedure: OutPutTo ; Module: " & mdl
   strMyMsg = "Error Number: " & Err.Number & Chr(13) & Chr(10)
   strMyMsg = strMyMsg & "Error Description :" & Err.Description & _
      Chr(13) & Chr(10)
   MsgBox strMyMsg, vbExclamation, strMyTitle
   Resume Exit_OutPutModules
End Function