ACC2000: Can't Use PrtDevMode or PrtMip Property with MDE Files

In an MDE file, you cannot use the PrtDevMode or PrtMip property to change printer information for forms and reports. If you try to modify printer information by programmatically using the PrtDevMode or PrtMip property, you may receive the following error message:

To modify printer information using the PrtDevMode or PrtMip property, the form or report must first be opened in Design view. However, forms, reports, and modules cannot be opened in Design mode within an MDE file.

Instead of creating MDE files, create a Microsoft Access database and add Microsoft Access security to the database. Adding security to your Microsoft Access database (MDB) will prevent users from viewing the design of your forms, reports, modules, and so on.

IMPORTANT: This resolution assumes that you understand the Microsoft Access Security model.

If you use a Microsoft Access database that has been secured, you can use the CreateWorkspace method to create a session for the Administrator of the database while programmatically modifying printer information using the PrtDevMode or PrtMip property.

For more information on Microsoft Access Security, see the following documentation: The following example uses the default Admin user as the Administrator of the Northwind database, and allows user Guest to open a report, change its margin settings, and then preview the report.

CAUTION: Following the steps in this example will modify the sample database Northwind.mdb. You may want to back up the Northwind.mdb file and perform these steps on a copy of the database.

1. Open the sample database Northwind.mdb.
2. Create a module and type the following lines in the Declarations section:

    Option Explicit
   
    Type str_PRTMIP
       strRGB As String * 28
    End Type
   
    Type type_PRTMIP
       lngLeftMargin As Long
       lngTopMargin As Long
       lngRightMargin As Long
       lngBotMargin As Long
       lngDataOnly As Long
       lngWidth As Long
       lngHeight As Long
       lngDefaultSize As Long
       lngColumns As Long
       lngColumnSpacing As Long
       lngRowSpacing As Long
       lngItemLayout As Long
       lngFastPrint As Long
       lngDatasheet As Long
    End Type
   					

3. Save and close the module.
4. Open a new form not based on any table or query in Design view.
5. Add a command button to the form.
6. Set the command button's OnClick property to the following event procedure:

    Private Sub Command0_Click()
   
    ' This example shows how to set report margins in a secured
    ' database.
    Dim wrkAdmin As Workspace
    Dim dbs As Database
    Dim ctrReports As Container
    Dim docReport As Document
    Dim PrtMipString As str_PRTMIP
    Dim PM As type_PRTMIP
    Dim Rpt As Report
    Dim strName As String
   
    strName = "Summary of Sales by Year"
   
    ' Create a new session and assign it to the database administrator.
    Set wrkAdmin = DBEngine.CreateWorkspace("AdminWorkspace", "Admin", _
    "Admin", dbUseJet)
    ' Be sure to change the path in this next line to match your path to
    ' Northwind.mdb.
    Set dbs = wrkAdmin.OpenDatabase("C:\Northwind.mdb", False)
    Set ctrReports = dbs.Containers!Reports
    Set docReport = ctrReports.Documents(strName)
    ' Give the Users group full permissions to this report.
    docReport.UserName = "Users"
    docReport.Permissions = dbSecFullAccess
   
    ' Close the session.
    wrkAdmin.Close
   
    ' Open the report in Design view and set the report object variable.
    DoCmd.Echo False
    DoCmd.OpenReport strName, acDesign
   
    Set Rpt = Reports(strName)
    ' Assign the reports current device information.
    PrtMipString.strRGB = Rpt.PrtMip
   
    ' Assign the device information into its various components.
    LSet PM = PrtMipString
   
    ' The new margin settings to be used are half inch.
    ' Note: The Summary of Sales by Year report has 1" margins by
    ' default.
    PM.lngLeftMargin = 0.5 * 1440
    PM.lngTopMargin = 0.5 * 1440
    PM.lngRightMargin = 0.5 * 1440
    PM.lngBotMargin = 0.5 * 1440
   
    ' Update the device information with the new settings.
    LSet PrtMipString = PM
   
    Rpt.PrtMip = PrtMipString.strRGB
   
    ' Close the design of the report, saving the changes,
    ' and then preview the report.
    DoCmd.Close acReport, strName, acSaveYes
    DoCmd.OpenReport strName, acViewPreview
    DoCmd.Echo True
   
    ' Re-create a new session, assigning it to the database
    ' administrator.
    Set wrkAdmin = DBEngine.CreateWorkspace("AdminWorkspace", "Admin", _
    "Admin", dbUseJet)
    ' Be sure to enter the correct path in this next line as well.
    Set dbs = wrkAdmin.OpenDatabase("C:\Northwind.mdb", False)
    Set ctrReports = dbs.Containers!Reports
    Set docReport = ctrReports.Documents(strName)
   
    ' Assign Read permissions for to this report back to the Users group.
    docReport.UserName = "Users"
    docReport.Permissions = dbSecReadSec
   
    ' Close the session.
    wrkAdmin.Close
   
    End Sub
   					

7. Save the form as Form1 and close it.
8. Remove all permissions for the Users group for all objects.
9. Create a new user called Guest.
10. Assign the following permissions to the Guest user:
    1. Open/Run on the Current Database
    2. Read Data and Read Design on the Order Details table
    3. Read Data and Read Design on the Orders table
    4. Read Data and Read Design on the Order Subtotals query
    5. Read Data and Read Design on the Summary of Sale by Year query
    6. Open/Run on the Form1 form
    7. Open/Run, Read Design and Modify Design on the "Summary of Sales by Year" report
11. Assign the password Admin to the Admin user.
12. Close and restart Microsoft Access.
13. Type Guest as the logon name, and press ENTER.
14. Open the Form1 form in Form view, and click the command button. Note that the "Summary of Sales by Year" report displays in print preview with half-inch margins.

NOTE: Because you have assigned only Open/Run permissions to the Form1 form, it is impossible for the user to open the form in Design view in order to discover what the Admin's password is. However, keep in mind that a properly secured database would never use the default Admin account as the administrator of a database.

Printer page setup properties such as PrtDevMode and PrtMip enable you to programmatically manipulate the printer information specified for Microsoft Access forms and reports. The PrtDevMode and PrtMip properties enable you to read a form or report's current printer settings as well as update the printer settings.

Unlike run-time applications, which allow the PrtDevMode and PrtMip properties to open forms and reports in Design view, MDE file formats do not allow forms and reports to be opened in Design view.

Steps to Reproduce Behavior

1. Repeat steps 1 through 7 in the "Resolution" section of this article.
2. Set the command button's OnClick property to the following event procedure:

    Dim PrtMipString As str_PRTMIP
    Dim PM As type_PRTMIP
    Dim rpt As Report
    Dim strName As String
   
    DoCmd.Echo False
    strName = "Summary of Sales by Year"
   
    DoCmd.OpenReport strName, acDesign
    Set rpt = Reports(strName)
   
    PrtMipString.strRGB = rpt.PrtMip
    LSet PM = PrtMipString
   
    PM.lngLeftMargin = 1 * 1440
    PM.lngTopMargin = 1 * 1440
    PM.lngRightMargin = 1 * 1440
    PM.lngBotMargin = 1 * 1440
   
    LSet PrtMipString = PM
    rpt.PrtMip = PrtMipString.strRGB
   
    DoCmd.Close acReport, strName, acSaveYes
    DoCmd.OpenReport strName, acViewPreview
    DoCmd.Echo True
   					

3. Save the form as Form1 and open it in Form view. Note that you can preview the report without any errors.
4. Close the report and the form.
5. On the Tools menu, click Database Utilities, and then click Make MDE File, and save the Northwind database in an MDE format.
6. Open Northwind.mde and double-click the Form1 form to open it.
7. Click the command button. Note that you receive the following error message:
   The expression On Click you entered as the event property setting produced the following error: That command isn't available in an MDE database.
   
   The expression may not result in the name of a macro, the name of a user-defined function, or [Event Procedure].
   
   There may have been an error evaluating the function, event, or macro.

For more information about PrtDevMode or PrtMip property, in the Visual Basic Editor, click Microsoft Visual Basic Help on the Help menu, type "PrtDevMode Property or PrtMip Property" in the Office Assistant or the Answer Wizard, and then click Search to view the topic. For additional information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base: