Microsoft KB Archive Search

Notice: This website is an unofficial Microsoft Knowledge Base (hereinafter KB) archive and is intended to provide a reliable access to deleted content from Microsoft KB. All KB articles are owned by Microsoft Corporation. Read full disclaimer for more details.

  1. Home
  2. How to access public folder contents from an ASP page

How to access public folder contents from an ASP page

View products that this article applies to.

This article was previously published under Q178552

↑ Back to the top

Summary

This article describes how to view the contents of a Public Folder from an Active Server Page (ASP) page. This article contains sample code that demonstrates this technique.

↑ Back to the top

More information

A difference between viewing Public Folders in Visual Basic and from Visual Basic Script in an ASP page, is that in Visual Basic Script you need to use the GetFolder() method, which necessitates knowing the FolderID. (The error
MAPI_E_FAILONEPROVIDER (8004011D)
may occur if you attempt to traverse the folders instead.) If you do not know the FolderID, you need to determine the FolderID programmatically.

The following code looks for the "*Welcome to Public Folders*" folder in the "Public Folders" collection. Insert the following code into an ASP file and make appropriate modifications for server, mailbox, and folders:

Sample code

<%@ LANGUAGE="VBSCRIPT" %>

   <HTML>
   <HEAD>
   <META NAME="GENERATOR" Content="Microsoft Visual InterDev 1.0">
   <META HTTP-EQUIV="Content-Type" content="text/html;charset=iso-8859-1">
   <TITLE>Document Title</TITLE>
   </HEAD>
   <BODY>

   <!-- Insert HTML here -->
   <%
   CONST strServer      = "MyServer"
   CONST strMailbox     = "MyMailbox"
   Dim objSession
   Dim objMessages
   Dim objOneMessage
   Dim objInfoStores
   Dim objInfoStore
   Dim objTopFolder
   Dim objFolders
   Dim objSubFolder
   Dim objTargetFolder
   Dim strProfileInfo
   Dim i
   Dim bstrPublicRootID

   strProfileInfo = strServer & vblf & strMailbox
   Set objSession = Server.CreateObject("MAPI.Session")
   objSession.Logon , , , False, , True, strProfileInfo
   Set objInfoStores = objSession.InfoStores

   For i = 1 To objInfoStores.Count
    If objInfoStores.Item(i)= "Public Folders" Then
       Set objInfoStore=objInfoStores.Item(i)
       Exit For
    End If
   Next

   bstrPublicRootID = objInfoStore.Fields.Item( &H66310102 ).Value
   Set objTopFolder = objSession.GetFolder(bstrPublicRootID, _
               objInfoStore.ID)
   Set objFolders = objTopFolder.Folders
   Set objFolder = objFolders.GetFirst()

   Do Until objFolder.Name = "*Welcome to Public Folders*"
    Set objFolder=objFolders.GetNext()
   Loop

   Set objMessages = objFolder.Messages
   Response.Write("10 objMessages.Count = " & objMessages.Count _
         & "<br>")
   For Each objOneMessage in objMessages
     Response.Write("objOneMessage.Subject = " & _
            objOneMessage.Subject & "<br>")
     Response.Write("objOneMessage.Text = " & objOneMessage.Text & _
           "<br> <br>")
   Next

   objSession.Logoff
   Set objOneMessage = Nothing
   Set objMessages = Nothing
   Set objFolder = Nothing
   Set objTopFolder = Nothing
   Set objSession = Nothing
   %>
   </BODY>
   </HTML>
Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs.
If you have limited programming experience, you may want to contact a Microsoft Certified Partner or Microsoft Advisory Services. For more information, visit these Microsoft Web sites:

Microsoft Certified Partners - https://partner.microsoft.com/global/30000104

Microsoft Advisory Services - http://support.microsoft.com/gp/advisoryservice

For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site: http://support.microsoft.com/default.aspx?scid=fh;EN-US;CNTACTMS

↑ Back to the top

Keywords: KB178552, kbmsg, kbinetdev, kbhowto, kbfaq, kbcode

↑ Back to the top

Article Info
Article ID : 178552
Revision : 8
Created on : 10/25/2007
Published on : 10/25/2007
Exists online : False
Views : 575