FIX: "URL" and "Destination Host Name" values are unreadable in the web proxy log of Forefront Threat Management Gateway 2010 are unreadable

'Define the constants needed.
Const strVpsGUID = "{143F5698-103B-12D4-FF34-1F34767DEABC}"
Const strVpsPropertyName = "PersistLogAsPunycode"
Const Error_FileNotFound = &H80070002
Set objArgs = wscript.Arguments
fInvalidParameterValue = False
if objArgs.Count > 0 then
    if objArgs(0) = "0" then
        fPersistLogAsPunycode = False
    elseif objArgs(0) = "1" then
        fPersistLogAsPunycode = True
    else
        fInvalidParameterValue = True
    end if
end if
if objArgs.Count <> 1 or fInvalidParameterValue then
    wscript.echo "Usage: SetPersistLogAsPunycode.vbs <0|1>"
    wscript.echo
    wscript.echo "Control how log fields that may contain punycode-encoded parts are"
    wscript.echo "stored in the persistent log."
    wscript.echo
    wscript.echo "    0 - Persist the applicable log fields as ASCII (the default behavior)"
    wscript.echo "    1 - Persist the applicable log fields as Punycode"
    wscript.Quit 2
end if
set objLogging = CreateObject("FPC.Root").GetContainingArray().Logging
Set objVPSet = OpenVPSet(objLogging, strVpsGUID)
objVPSet.Value(strVpsPropertyName) = fPersistLogAsPunycode
objLogging.Save
function OpenVPSet(objParent, strVpsGUID)
    Set objVPSets = objParent.VendorParametersSets
    On Error Resume Next
    Set OpenVPSet = objVPSets.Item(strVpsGUID)
    ' Save the Err properties in case it needs to be re-raised
    errNumber      = Err.Number
    errSource      = Err.Source
    errDescription = Err.Description
    errHelpFile    = Err.HelpFile
    errHelpContext = Err.HelpContext
    
    On Error GoTo 0
    
    if errNumber = Error_FileNotFound Then
        Set OpenVPSet = objVPSets.Add(strVpsGUID)
    Elseif errNumber < 0 Then
        ' An error other than "file not found" occured -- re-raise the error,
        ' this time not under "On Error Resume Next"
        Err.Raise errNumber, errSource, errDescription, errHelpFile, errHelpContext
    End If
end function