The Folder Redirection policy does not work if a previous user sets a redirected folder to an offline mode in Windows 7 or in Windows Server 2008 R2

'
' THIS CODE AND INFORMATION IS PROVIDED "AS IS" WITHOUT WARRANTY OF
' ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING BUT NOT LIMITED TO
' THE IMPLIED WARRANTIES OF MERCHANTABILITY AND/OR FITNESS FOR A
' PARTICULAR PURPOSE.
'
' Copyright (c) Microsoft Corporation. All rights reserved.
'
'
' Usage: CscTransition.vbs /ItemPath:<path> /Online|Offline [/Force] [/Machine:value] [/User:value] [/Password:value]
'
' 
' Set an item to an online or offline state.
'
'     /Online    - Transition online
'     /Offline   - Transition offline
'     /Force     - For offline transition, force any open handles closed.  Default is no-force.
'
'
 
const cComputerName = "LocalHost"
const cWMINamespace = "root\cimv2"
const cWMIClass     = "Win32_OfflineFilesCache"
 
set objWMILocator = WScript.CreateObject("WbemScripting.SWbemLocator")
 
'
' Process commandline arguments
'
strItemPath = WScript.Arguments.Named("ItemPath")'
if Len(strItemPath) = 0 Then
    Wscript.Echo "ItemPath parameter required"
    Err.Raise 449  ' "argument not optional" error
End if
 
bOnline   = False
bOffline  = False
bForce    = False
 
If WScript.Arguments.Named.Exists("Online") Then
    bOnline = True
End If
 
If WScript.Arguments.Named.Exists("Offline") Then
    bOffline = True
End If
 
If WScript.Arguments.Named.Exists("Force") Then
    bForce = True
End if
 
If NOT bOnline AND NOT bOffline Then
    WScript.Echo "Must specify either Online or Offline parameter."
    Err.Raise 449  ' "argument not optional" error
End if
 
If bOnline AND bOffline Then
    WScript.Echo "Only one of Online and Offline parameters may be specified."
    Err.Raise 450 ' "Wrong number of arguments" error
End if
 
 
strComputerName = WScript.Arguments.Named("Machine")
If Len(strComputerName) = 0 Then strComputerName = cComputerName
 
strUserID = WScript.Arguments.Named("User")
If Len(strUserID) = 0 Then strUserID = ""
 
strPassword = WScript.Arguments.Named("Password")
If Len(strPassword) = 0 Then strPassword = ""
 
 
Set objWMIServices = objWMILocator.ConnectServer(strComputerName, _
                                                 cWMINameSpace, _
                                                 strUserID, _
                                                 strPassword)
 
 
'
' Transition control flags from Win32_OfflineFilesCache.TransitionOnline and TransitionOffline
'
const fInteractive = &H00000001
const fConsole     = &H00000002
 
TransitionFlags = fConsole + _
                  fInteractive
 
 
'
' Note that Win32_OfflineFilesCache is a singleton.
'
Set objCache = objWMIServices.Get("Win32_OfflineFilesCache=@")
 
WScript.Echo "Path = " & strItemPath & "  bOnline = " & bOnline
 
If bOnline Then
    objCache.TransitionOnline strItemPath, TransitionFlags
    WScript.Echo strItemPath & " is online."
Else
    bOpenFiles = False
    objCache.TransitionOffline strItemPath, bForce, TransitionFlags, bOpenFiles
 
    If bOpenFiles Then
        WScript.Echo strItemPath & " is not offline.  Open Files prevent offline transition."
    Else
        WScript.Echo strItemPath & " is offline."
    End If
End If