The unrealized VAT lines that have the same VAT identifier are not grouped in the "VAT Register - Print" report in the Italian version of Microsoft Dynamics NAV 2009

Installation information

Code changes

1. Add a global variable, and then specify the variable as follows:
   • Name: VATBookEntryTemp2
   • DataType: Record
   • Subtype: VAT Book Entry
   • Enable the Temporary property.
2. Add a local variable in the UnrealizedVAT - OnAfterGetRecord trigger, and then specify the variable as follows:
   • Name: VATBookEntry2
   • DataType: Record
   • Subtype: VAT Book Entry
3. Change the code in the UnrealizedVAT - OnAfterGetRecord trigger as follows:
   Existing code

   ...
   VATEntry.GET("Unrealized VAT Entry No.");
   
   Name := '';
   VATReg := '';
   
   // Delete the following lines.
   IF "VAT Register".Type = "VAT Register".Type::Purchase THEN 
     DocumentTotal := DocumentTotalCalculation("Transaction No.","Document No.","Unrealized VAT Entry No.") 
   ELSE 
     DocumentTotal := -DocumentTotalCalculation("Transaction No.","Document No.","Unrealized VAT Entry No."); 
   // End of the lines.
   
   IF "Document Type" = "Document Type"::Invoice THEN
   ...
   

   Replacement code

   ...
   // Add the following lines.
   VATBookEntryTemp2.SETRANGE("Entry No.","Entry No.");
   IF VATBookEntryTemp2.FINDSET THEN
     CurrReport.SKIP
   ELSE BEGIN
     IF "VAT Register".Type = "VAT Register".Type::Purchase THEN
       DocumentTotal := DocumentTotalCalculation("Transaction No.","Document No.","Unrealized VAT Entry No.")
     ELSE
       DocumentTotal := -DocumentTotalCalculation("Transaction No.","Document No.","Unrealized VAT Entry No.");
   
     VATBookEntry2.RESET;
     VATBookEntry2.SETRANGE("Document No.","Document No.");
     VATBookEntry2.SETRANGE(Type,Type);
     VATBookEntry2.SETRANGE("VAT Bus. Posting Group","VAT Bus. Posting Group");
     VATBookEntry2.SETRANGE("VAT Prod. Posting Group","VAT Prod. Posting Group");
     VATBookEntry2.SETRANGE("VAT %","VAT %");
     VATBookEntry2.SETRANGE("Deductible %","Deductible %");
     VATBookEntry2.SETRANGE("VAT Identifier","VAT Identifier");
     VATBookEntry2.SETRANGE("Transaction No.","Transaction No.");
     VATBookEntry2.SETFILTER("Unrealized VAT Entry No.",'<>%1',"Unrealized VAT Entry No.");
     IF VATBookEntry2.FINDFIRST THEN BEGIN
       REPEAT
         VATBookEntryTemp2 := VATBookEntry2;
         VATBookEntryTemp2.INSERT;
   
         VATBookEntry2.CALCFIELDS(Base, Amount,"Unrealized Base","Unrealized Amount","Nondeductible Base",
           "Nondeductible Amount");
         Base := Base + VATBookEntry2.Base;
         Amount := Amount + VATBookEntry2.Amount;
         "Unrealized Base" := "Unrealized Base" + VATBookEntry2."Unrealized Base";
         "Unrealized Amount" := "Unrealized Amount" + VATBookEntry2."Unrealized Amount";
         "Nondeductible Base" := "Nondeductible Base" + VATBookEntry2."Nondeductible Base";
         "Nondeductible Amount" := "Nondeductible Amount" + VATBookEntry2."Nondeductible Amount";
   
       IF "VAT Register".Type = "VAT Register".Type::Purchase THEN
         DocumentTotal := DocumentTotal +
           DocumentTotalCalculation(VATBookEntry2."Transaction No.",
           VATBookEntry2."Document No.",
           VATBookEntry2."Unrealized VAT Entry No.")
       ELSE
         DocumentTotal := DocumentTotal +
           -DocumentTotalCalculation(VATBookEntry2."Transaction No.",
           VATBookEntry2."Document No.",
           VATBookEntry2."Unrealized VAT Entry No.");
   
       IF (PrintingType = PrintingType::Final) AND
         NOT Preview
       THEN BEGIN
         VATBookEntry2."Printing Date" := TODAY;
         VATBookEntry2.MODIFY;
       END;
       UNTIL VATBookEntry2.NEXT = 0;
     END;
   END;
   // End of the lines.
   
   VATEntry.GET("Unrealized VAT Entry No.");
   
   Name := '';
   VATReg := '';
   
   IF "Document Type" = "Document Type"::Invoice THEN
   ...
   

Prerequisites

• The Italian version of Microsoft Dynamics NAV 2009 R2
• The Italian version of Microsoft Dynamics NAV 2009 Service Pack 1

Removal information